Initial commit

figs/condensate.fig/condensate.gnuplot

@@ -0,0 +1,41 @@
+set ylabel "$\\tilde\\eta$" norotate offset -1,0
+set xlabel "$\\rho$"
+
+set xtics 1e-6, 100, 100
+set xtics add ("$10^{-6}$" 0.000001, "$10^{-4}$" 0.0001, "$10^{-2}$" 0.01, "$1$" 1.0, "$10^2$" 100)
+unset mxtics
+
+#set ytics 0.6, 0.1
+set mytics 2
+
+set xrange [4e-8:100]
+
+set yrange [:0.06]
+
+# default output canvas size: 12.5cm x 8.75cm
+set term lua tikz size 8,6 standalone
+
+set key top left box linetype rgbcolor"#999999" width 0.3 height 0.3 spacing 1.3
+
+
+# set linestyle
+set style line 1 linetype rgbcolor "#4169E1" linewidth 2 dashtype "."
+set style line 2 linetype rgbcolor "#DC143C" linewidth 2
+set style line 3 linetype rgbcolor "#32CD32" linewidth 2 dashtype "-"
+set style line 4 linetype rgbcolor "#4B0082" linewidth 2
+set style line 5 linetype rgbcolor "#DAA520" linewidth 2
+set style line 6 linetype rgbcolor "#999999" linewidth 1.5 dashtype (1,5)
+
+set pointsize 1
+
+set logscale x
+
+a=0.7666858699084325
+
+plot \
+ "simpleq.dat" using 1:($3<1e-5 ? $2 : 1/0) with lines ls 1 title "simple",\
+ "medeq.dat" using 1:($3<1e-5 ? $2 : 1/0) with lines ls 3 title "med",\
+ "bigeq.dat" using 1:($3<1e-5 ? $2 : 1/0) with lines ls 5 title "big",\
+ "2020-08-27+0.5.dat" using 1:(1-$3) with points ls 2 title "QMC" ,\
+ 8./(3*sqrt(pi))*sqrt(x*a**3) ls 6 title "Bog"
+