set ylabel "$\\rho_m\\ (\\mathrm{g}/\\mathrm{cm}^3)$"
set xlabel "$T\\ (\\mathrm{K})$"

set xrange[0:300]
set yrange [0:20]

# default output canvas size: 12.5cm x 8.75cm
set term lua tikz size 12.5,8.75 standalone

set key off

# set linestyle
set style line 1 linetype rgbcolor "#4169E1" linewidth 3
set style line 2 linetype rgbcolor "#DC143C" linewidth 3
set style line 3 linetype rgbcolor "#32CD32" linewidth 3
set style line 4 linetype rgbcolor "#4B0082" linewidth 3
set style line 5 linetype rgbcolor "#DAA520" linewidth 3
set style line 6 linetype rgbcolor "#000000" linewidth 3

set pointsize 0.6

set label "\\bf BEC" at 10,10 front textcolor "white"
set label "\\bf Gas" at 150,10 front textcolor "white"

kb=1.380649e-23
hbar=1.054571817e-34
cst=0.05864362134764442
m=1.66053906660e-27*4

plot (2*m/hbar/hbar*kb*x)**1.5*cst*m/1000 with filledcurves x2 linestyle 1 ,\
 (2*m/hbar/hbar*kb*x)**1.5*cst*m/1000 with filledcurves x1 linestyle 2, \
 (2*m/hbar/hbar*kb*x)**1.5*cst*m/1000 with lines linestyle 6