set ylabel "$N_\\kappa-N_\\kappa^{(\\mathrm{Bog})}$"
set xlabel "$\\kappa\\rho^{-1/3}$"

#set xtics 1e-6, 1000, 1e6
#set xtics add ("$10^{-6}$" 0.000001, "$10^{-3}$" 0.001, "$10^{0}$" 1, "$10^{3}$" 1000, "$10^6$" 1000000)
#unset mxtics
set xrange [:20]

#set ytics 0, 1e-5, 2e-5	
#set ytics add ("$10^{-5}$" 1e-5)
#set mytics
#set yrange [-0.25:0.30]

# default output canvas size: 12.5cm x 8.75cm
set term lua tikz size 8,6 standalone

set key top right box linetype rgbcolor"#999999" width 5 height 0.3 spacing 1.3

rgb(r,g,b) = 65536 * int(r) + 256 * int(g) + int(b)
circle_2_rgb(x) = (x < 1./6 ? rgb(255,x*6*255,0) : \
		  (x < 2./6 ? rgb((2./6-x)*6*255,255,0) : \
		  (x < 3./6 ? rgb(0,255,(x-2./6)*6*255) : \
		  (x < 4./6 ? rgb(0,(4./6-x)*6*255,255) : \
		  (x < 5./6 ? rgb((x-4./6)*6*255,0,255) : \
		              rgb(255,0,(1-x)*6*255) \
		  )))))


set style line 1 linetype rgbcolor "#0000FF" linewidth 2 dashtype (2,6)
set style line 2 linetype rgbcolor "#1E90FF" linewidth 2 dashtype (2,4)
set style line 3 linetype rgbcolor "#FF0000" linewidth 2
set style line 4 linetype rgbcolor "#1CEB2E" linewidth 2 dashtype (2,2)
set style line 5 linetype rgbcolor "#228B22" linewidth 2 dashtype (4,2)
set style line 6 linetype rgbcolor "#2F4F4F" linewidth 2 dashtype (6,2)
set style line 7 linetype rgbcolor "#000000" linewidth 1

# scattering length
a8=3.233946179033422
# Bogolyubov prediction
Nk(x,rho)=-0.5+0.5*(x**2+2*rho*4*pi*a8)/sqrt(x**4+4*x**2*rho*4*pi*a8)

plot \
 0 ls 7 notitle ,\
 "medeq_0.3.dat" using ($1/0.3e-3**(1./3)):(4*pi*$1**2*($2*0.3e-3-Nk($1,0.3e-3))) with lines ls 1 title "$\\rho=0.3\\times10^{-3}$" ,\
 "medeq_1.1.dat" using ($1/1.1e-3**(1./3)):(4*pi*$1**2*($2*1.1e-3-Nk($1,1.1e-3))) with lines ls 2 title "$\\rho=1.1\\times10^{-3}$" ,\
 "medeq_1.9.dat" using ($1/1.9e-3**(1./3)):(4*pi*$1**2*($2*1.9e-3-Nk($1,1.9e-3))) with lines ls 3 title "$\\rho=1.9\\times10^{-3}$" ,\
 "medeq_2.7.dat" using ($1/2.7e-3**(1./3)):(4*pi*$1**2*($2*2.7e-3-Nk($1,2.7e-3))) with lines ls 4 title "$\\rho=2.7\\times10^{-3}$" ,\
 "medeq_3.5.dat" using ($1/3.5e-3**(1./3)):(4*pi*$1**2*($2*3.5e-3-Nk($1,3.5e-3))) with lines ls 5 title "$\\rho=3.5\\times10^{-3}$" ,\
 "medeq_4.3.dat" using ($1/4.3e-3**(1./3)):(4*pi*$1**2*($2*4.3e-3-Nk($1,4.3e-3))) with lines ls 6 title "$\\rho=4.3\\times10^{-3}$"