#set title "Big equation"
set ylabel norotate "$\\mathcal S(\\kappa)$"
set xlabel "$\\kappa$"

#set xtics 1e-6, 1000, 1e6
#set xtics add ("$10^{-6}$" 0.000001, "$10^{-3}$" 0.001, "$10^{0}$" 1, "$10^{3}$" 1000, "$10^6$" 1000000)
#unset mxtics
set xrange [:8]

#set ytics 0, 1e-5, 2e-5	
#set ytics add ("$10^{-5}$" 1e-5)
#set mytics
set yrange [0.99998:1.0001]

# default output canvas size: 12.5cm x 8.75cm
set term lua tikz size 8,6 standalone

set key top right box linetype rgbcolor"#999999" width 2.5 height 0.3 spacing 1.3

rgb(r,g,b) = 65536 * int(r) + 256 * int(g) + int(b)
circle_2_rgb(x) = (x < 1./6 ? rgb(255,x*6*255,0) : \
		  (x < 2./6 ? rgb((2./6-x)*6*255,255,0) : \
		  (x < 3./6 ? rgb(0,255,(x-2./6)*6*255) : \
		  (x < 4./6 ? rgb(0,(4./6-x)*6*255,255) : \
		  (x < 5./6 ? rgb((x-4./6)*6*255,0,255) : \
		              rgb(255,0,(1-x)*6*255) \
		  )))))


set style line 1 linetype rgbcolor circle_2_rgb(0.0) linewidth 2 dashtype (9,9)
set style line 2 linetype rgbcolor circle_2_rgb(0.17) linewidth 2 dashtype (7,7)
set style line 3 linetype rgbcolor circle_2_rgb(0.33) linewidth 2 dashtype (5,5)
set style line 4 linetype rgbcolor circle_2_rgb(0.5) linewidth 2 dashtype (3,3)
set style line 5 linetype rgbcolor circle_2_rgb(0.67) linewidth 2 dashtype (1,1)
set style line 6 linetype rgbcolor circle_2_rgb(0.83) linewidth 2


plot \
 "bigeq_5.dat" using 1:(1+$2/1e-5) with lines ls 1 title "$\\rho=10^{-5}$" ,\
 "bigeq_4.dat" using 1:(1+$2/1e-4) with lines ls 2 title "$\\rho=10^{-4}$" ,\
 "bigeq_3.dat" using 1:(1+$2/1e-3) with lines ls 3 title "$\\rho=10^{-3}$" ,\
 "bigeq_2.dat" using 1:(1+$2/1e-2) with lines ls 4 title "$\\rho=10^{-2}$" ,\
 "bigeq_1.dat" using 1:(1+$2/1e-1) with lines ls 5 title "$\\rho=10^{-1}$" ,\
 "bigeq_0.3.dat" using 1:(1+$2/0.3) with lines ls 6 title "$\\rho=0.3$"