# default output canvas size: 12.5cm x 8.75cm
set term lua tikz size 8,6 standalone

set multiplot

set ylabel "$\\frac jk$" norotate
set xlabel "$\\frac{t\\omega}{2\\pi}$"

set xtics 0,0.25
set ytics -0.2,0.1

set yrange [-0.2:0.55]

# no key
set key off

# set linestyle
set style line 1 linetype rgbcolor "#4169E1" linewidth 3
set style line 2 linetype rgbcolor "#DC143C" linewidth 3
set style line 3 linetype rgbcolor "#32CD32" linewidth 3
set style line 4 linetype rgbcolor "#4B0082" linewidth 3
set style line 5 linetype rgbcolor "#DAA520" linewidth 3

set pointsize 0.6


plot "mc.dat" using 1:5 with lines linestyle 1, \
"cn.dat" using 1:3 with lines linestyle 2

## inset
set origin 0.631,0.65
set size .3,.3

# remove margins
set lmargin 0
set rmargin 0
set tmargin 0
set bmargin 0

# clear background of inset
clear

# no labels
unset ylabel
unset xlabel

# set xtics on top
set x2tics 0,0.0005
#set ytics -0.025,0.005
unset xtics
unset ytics

set yrange [-0.025:0.005]

plot "mc_short.dat" using 1:5 with lines linestyle 1, \
"cn_short.dat" using 1:3 with lines linestyle 2